Deploy Qt libraries; fix platforms NSIS installer include

CMakeLists.txt

@@ -1187,6 +1187,15 @@ if(NOT HEADLESS_ONLY)
 	if(WITH_QT_EDITOR)
 		set_target_properties(openclonk PROPERTIES COMPILE_DEFINITIONS WITH_QT_EDITOR)
 		target_link_libraries(openclonk Qt5::Widgets)
+
+		# Deploy dependency libraries and platforms/ folder
+		if(WIN32)
+			include(DeployQt)
+			windeployqt(openclonk)
+		elseif(APPLE)
+			include(DeployQt)
+			macdeployqt(nitroshare-client)
+		endif()
 	endif()
 
 	if(HAVE_BACKWARD)

cmake/DeployQt.cmake

@@ -0,0 +1,89 @@
+# The MIT License (MIT)
+#
+# Copyright (c) 2018 Nathan Osman
+#
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+#
+# The above copyright notice and this permission notice shall be included in
+# all copies or substantial portions of the Software.
+#
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+find_package(Qt5Core REQUIRED)
+
+# Retrieve the absolute path to qmake and then use that path to find
+# the windeployqt and macdeployqt binaries
+get_target_property(_qmake_executable Qt5::qmake IMPORTED_LOCATION)
+get_filename_component(_qt_bin_dir "${_qmake_executable}" DIRECTORY)
+
+find_program(WINDEPLOYQT_EXECUTABLE windeployqt HINTS "${_qt_bin_dir}")
+if(WIN32 AND NOT WINDEPLOYQT_EXECUTABLE)
+    message(FATAL_ERROR "windeployqt not found")
+endif()
+
+find_program(MACDEPLOYQT_EXECUTABLE macdeployqt HINTS "${_qt_bin_dir}")
+if(APPLE AND NOT MACDEPLOYQT_EXECUTABLE)
+    message(FATAL_ERROR "macdeployqt not found")
+endif()
+
+# Add commands that copy the required Qt files to the same directory as the
+# target after being built as well as including them in final installation
+function(windeployqt target)
+
+    # Run windeployqt immediately after build
+    add_custom_command(TARGET ${target} POST_BUILD
+        COMMAND "${CMAKE_COMMAND}" -E
+            env PATH="${_qt_bin_dir}" "${WINDEPLOYQT_EXECUTABLE}"
+                --verbose 0
+                --no-compiler-runtime
+                --no-angle
+                --release-with-debug-info
+                --no-translations
+                \"$<TARGET_FILE:${target}>\"
+        COMMENT "Deploying Qt..."
+    )
+
+    # windeployqt doesn't work correctly with the system runtime libraries,
+    # so we fall back to one of CMake's own modules for copying them over
+
+    # Doing this with MSVC 2015 requires CMake 3.6+
+    if((MSVC_VERSION VERSION_EQUAL 1900 OR MSVC_VERSION VERSION_GREATER 1900)
+            AND CMAKE_VERSION VERSION_LESS "3.6")
+        message(WARNING "Deploying with MSVC 2015+ requires CMake 3.6+")
+    endif()
+
+    set(CMAKE_INSTALL_UCRT_LIBRARIES TRUE)
+    include(InstallRequiredSystemLibraries)
+    foreach(lib ${CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS})
+        get_filename_component(filename "${lib}" NAME)
+        add_custom_command(TARGET ${target} POST_BUILD
+            COMMAND "${CMAKE_COMMAND}" -E
+                copy_if_different "${lib}" \"$<TARGET_FILE_DIR:${target}>\"
+            COMMENT "Copying ${filename}..."
+        )
+    endforeach()
+endfunction()
+
+# Add commands that copy the required Qt files to the application bundle
+# represented by the target.
+function(macdeployqt target)
+    add_custom_command(TARGET ${target} POST_BUILD
+        COMMAND "${MACDEPLOYQT_EXECUTABLE}"
+            \"$<TARGET_FILE_DIR:${target}>/../..\"
+            -always-overwrite
+        COMMENT "Deploying Qt..."
+    )
+endfunction()
+
+mark_as_advanced(WINDEPLOYQT_EXECUTABLE MACDEPLOYQT_EXECUTABLE)

tools/install/oc.nsi

@@ -101,7 +101,7 @@ Section
   File "*.dll"
 
   SetOutPath "$INSTDIR\platforms"
-  File "platforms/*.dll"
+  File "platforms\"
 
   SetOutPath "$INSTDIR"